root/trunk/midgard/data/configure.ac

dnl $Id$
dnl
dnl Process this file with autoconf to produce a configure script.
dnl
AC_INIT([midgard-data],[1.9.0alpha1])
AC_CONFIG_HEADERS([config.h])

dnl Automake is needed for the build system.
dnl
AM_INIT_AUTOMAKE([1.6 dist-bzip2])
AM_MAINTAINER_MODE

AC_PROG_CC(gcc cc)
AC_LANG(C)

dnl Check for midgard-config
AC_ARG_WITH([midgard-config],
            AC_HELP_STRING([--with-midgard-config=PATH],
                           [Location of the midgard-config program]),
            [MIDGARD_CONFIG="$withval"],
            [AC_PATH_PROG([MIDGARD_CONFIG],["midgard-config"])])
test -x "$MIDGARD_CONFIG" || AC_MSG_ERROR([midgard-config not found, use --with-midgard-config])
MIDGARD_CFLAGS=`"$MIDGARD_CONFIG" --cppflags`
MIDGARD_LIBS=`"$MIDGARD_CONFIG" --libs`
MIDGARD_PREFIX=`"$MIDGARD_CONFIG" --prefix`
AC_SUBST([MIDGARD_CFLAGS])
AC_SUBST([MIDGARD_LIBS])
AC_SUBST([MIDGARD_PREFIX])

if test "$MIDGARD_PREFIX" = "/usr"; then
  MGD_USR_PATH="/usr"
  MGD_ETC_PATH="/etc"
  MGD_VAR_PATH="/var"
else
  MGD_USR_PATH="$MIDGARD_PREFIX"
  MGD_ETC_PATH="$MIDGARD_PREFIX/etc"
  if test "$MIDGARD_PREFIX" = "/usr/local"; then
    MGD_VAR_PATH="/var/local"
  else
    MGD_VAR_PATH="$MIDGARD_PREFIX/var"
  fi
fi
AC_SUBST([MGD_USR_PATH])
AC_SUBST([MGD_VAR_PATH])
AC_SUBST([MGD_ETC_PATH])

MGD_BLOB_DIR="$MGD_VAR_PATH/lib/midgard/blobs"
MGD_SHARE_PATH="$MGD_USR_PATH/share/midgard"
MGD_CONFIG_PATH="$MGD_ETC_PATH/midgard"
AC_SUBST([MGD_BLOB_DIR])
AC_SUBST([MGD_SHARE_PATH])
AC_SUBST([MGD_CONFIG_PATH])

dnl Check php binary
dnl Check for midgard-config
AC_ARG_WITH([php],
        AC_HELP_STRING([--with-php=PATH],
        [Location of the php binary]),
        [PHP_BINARY="$withval"],
        [AC_PATH_PROG([PHP_BINARY],["php"])])
test -x "$PHP_BINARY" || AC_MSG_ERROR([php binary not found, use --with-php])
AC_SUBST([PHP_BINARY])

dnl Check for mysql binaries
AC_ARG_WITH([mysql-path],
            AC_HELP_STRING([--with-mysql-path=PATH],
                           [Path containing the MySQL binaries]),
            [MYSQL_PATH=$withval],
            [MYSQL_PATH=$PATH])
AC_ARG_WITH([mysql],
            AC_HELP_STRING([--with-mysql=PATH],
                           [Location of the mysql program]),
            [MYSQL=$withval],
            [AC_PATH_PROG([MYSQL],[mysql],[mysql],[$MYSQL_PATH])])
test -x "$MYSQL" || AC_MSG_ERROR([mysql not found, use --with-mysql])
AC_SUBST([MYSQL])
AC_ARG_WITH([mysqladmin],
            AC_HELP_STRING([--with-mysqladmin=PATH],
                           [Location of the mysqladmin program]),
            [MYSQLADMIN=$withval],
            [AC_PATH_PROG([MYSQLADMIN],[mysqladmin],[mysqladmin],[$MYSQL_PATH])])
test -x "$MYSQLADMIN" || AC_MSG_ERROR([mysqladmin not found, use --with-mysqladmin])
AC_SUBST([MYSQLADMIN])
AC_ARG_WITH([mysqldump],
            AC_HELP_STRING([--with-mysqldump=PATH],
                           [Location of the mysqldump program]),
            [MYSQLDUMP=$withval],
            [AC_PATH_PROG([MYSQLDUMP],[mysqldump],[mysqldump],[$MYSQL_PATH])])
test -x "$MYSQLDUMP" || AC_MSG_ERROR([mysqldump not found, use --with-mysqldump])
AC_SUBST([MYSQLDUMP])

dnl Check for apxs binary
AC_ARG_WITH([apxs],
            AC_HELP_STRING([--with-apxs=PATH],
                           [Location of the apxs program]),
            [APXS=$withval],
            [AC_PATH_PROG([APXS],[apxs])])
test -x "$APXS" || AC_MSG_ERROR([apxs not found, use --with-apxs])
AC_SUBST([APXS])

dnl Check for Apache settings

AC_MSG_CHECKING([for the Apache executable])
APACHE=`$APXS -q SBINDIR`/`$APXS -q TARGET`
AC_MSG_RESULT($APACHE)
AC_SUBST(APACHE)

AC_MSG_CHECKING([for the Apache module directory])
APACHE_LIBEXEC_PATH=`$APXS -q LIBEXECDIR`
AC_MSG_RESULT($APACHE_LIBEXEC_PATH)
AC_SUBST(APACHE_LIBEXEC_PATH)

AC_MSG_CHECKING([for the Apache configuration directory])
APACHE_CONF_PATH=`$APXS -q SYSCONFDIR`
AC_MSG_RESULT($APACHE_CONF_PATH)
AC_SUBST(APACHE_CONF_PATH)

AC_MSG_CHECKING([for the Apache configuration file])
APACHE_CONF=`$APACHE  -V | grep SERVER_CONFIG_FILE | sed 's/^.*FILE=//1' | sed 's/"//g'`
APACHE_CONF=$APACHE_CONF_PATH/`basename $APACHE_CONF`
AC_MSG_RESULT($APACHE_CONF)
AC_SUBST(APACHE_CONF)

dnl Check for Apache user and group

AC_MSG_CHECKING(for Apache user)
AC_ARG_WITH([apache-user],
            AC_HELP_STRING([--with-apache-user=user],
                           [The username of the Apache process]),
            [APACHE_USER=$withval],
            [APACHE_USER=`grep '^User ' $APACHE_CONF | sed -e 's/^User //'`])
id $APACHE_USER > /dev/null 2>&1 || \
  AC_MSG_ERROR([Apache user not found, use --with-apache-user])
AC_MSG_RESULT($APACHE_USER)
AC_SUBST(APACHE_USER)

AC_MSG_CHECKING(for Apache group)
AC_ARG_WITH([apache-group],
            AC_HELP_STRING([--with-apache-group=group],
                           [The group of the Apache process]),
            [APACHE_GROUP=$withval],
            [APACHE_GROUP=$APACHE_USER])
dnl TODO verify that the APACHE_GROUP exists
AC_MSG_RESULT($APACHE_GROUP)
AC_SUBST(APACHE_GROUP)
                    
dnl find 'install' command
AC_PROG_INSTALL

dnl Checks for libraries.

dnl Checks for header files.
AC_HEADER_STDC

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST

dnl Follow midgard core prefix
prefix="$MIDGARD_PREFIX"

SCHEMADIR_TEMP="$datadir/$PACKAGE"
eval "SCHEMADIR=$SCHEMADIR_TEMP"
AC_SUBST(SCHEMADIR)
AC_SUBST(REPLIGARD_OWNER)

AC_CONFIG_FILES([Makefile midgard_setup_globals.php datagard])
AC_OUTPUT